Másolás között Workbooks különböző nevek

szavazat
0

Én próbál a másolás / beillesztés értékek egyik nyitott munkafüzet a másikra. Sem a munkafüzetek lesz statikus neveket, úgyhogy nem lesz neve összhang. Mindkét én munkafüzetek nyitott lesz, és lesz az egyetlen nyitott fájlt.

Tud valaki segíteni kijavítani ezt a kódot a munka, amikor nem tudom, hogy a fájl vagy?

Range(M7:R19).Select
Selection.Copy
Windows(new template.xlsm).Activate
Range(M7).Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
    :=False, Transpose:=False
Windows(old template.xlsm).Activate
Range(S7:AT16).Select
Application.CutCopyMode = False
Selection.Copy
Windows(new template.xlsm).Activate
Range(U7).Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
    :=False, Transpose:=False
A kérdést 13/01/2020 23:58
a forrás felhasználó
Más nyelveken...                            


2 válasz

szavazat
1

Itt van, hogy két Workbookváltozó, hogy distinquish között az egyik, hogy a másolni kívánt honnan és hová szeretnénk illeszteni a . Tehát valami a kezdéshez lenne (mivel csak ezek a két munkafüzetek megnyitásához a futásidejű):

Sub Test()

Dim ws As Workbook, wbCopy As Workbook, wsPaste As Workbook

For Each wb In Application.Workbooks
    If IsNumeric(Right(wb.Name, 1)) Then
        Set wbCopy = wb
    Else
        Set wbPaste = wb
    End If
Next wb

'Continue coding... Below is just an option:
wbPaste.Worksheets(1).Range("U7:AV16").Value = wbCopy.Worksheets(1).Range("S7:AT16").Value
'Same thing for other ranges....  

End Sub

A második rész a kód, hogy fontolja meg. Azt nem tudom, melyik lapot olvassa, hogy mindkét munkafüzet, azt sem tudom, ha valóban szükség van, hogy a másolás / beillesztés. Az én például mentem az Worksheetindex 1, és azt feltételezték, egyszerű Valueátutalás lehet, amit valójában akar.

De az utóbbi két dolog, hogy fontolja meg.

Válaszolt 14/01/2020 00:23
a forrás felhasználó

szavazat
1

Alternatív módszer Likeüzemeltető teszt forrás / cél munkafüzetet. Továbbá olyan módon, hogy meghatározza forrás / cél tartományok hurkolható át a könnyű hibakeresés és frissítése később. Kód erősen kommentálta az egyértelműség kedvéért.

Sub tgr()

    Dim wb As Workbook
    Dim wsSource As Worksheet
    Dim wsDest As Worksheet

    'Check if exactly 2 workbooks are currently open
    If Application.Workbooks.Count <> 2 Then
        MsgBox "ERROR - There are [" & Application.Workbooks.Count & "] workbooks open." & Chr(10) & _
               "There must be two workbooks open:" & Chr(10) & _
               "-The source workbook (old template)" & Chr(10) & _
               "-The destination workbook"
        Exit Sub
    End If

    For Each wb In Application.Workbooks
        If wb.Name Like "*#.xls?" Then
            'Workbook name ends in number(s), this is the source workbook that will be copied from
            'You'll need to specify which sheet you're working with, this example code assumes the activesheet of that workbook
            Set wsSource = wb.ActiveSheet
        Else
            'Workbook name does not end in number(s), this is the source workbook that will be pasted to
            'You'll need to specify which sheet you're working with, this example code assumes the activesheet of that workbook
            Set wsDest = wb.ActiveSheet
        End If
    Next wb

    'Check if both a source and destination were assigned
    If wsSource Is Nothing Then
        MsgBox "ERROR - Unable to find valid source workbook to copy data from"
        Exit Sub
    ElseIf wsDest Is Nothing Then
        MsgBox "ERROR - Unable to find valid destination workbook to paste data into"
        Exit Sub
    End If

    'The first dimension is for how many times you need to define source and dest ranges, the second dimension should always be 1 to 2
    Dim aFromTo(1 To 2, 1 To 2) As Range
    'Add source copy ranges here:                       'Add destination paste ranges here
    Set aFromTo(1, 1) = wsSource.Range("M7:R19"):       Set aFromTo(1, 2) = wsDest.Range("M7")
    Set aFromTo(2, 1) = wsSource.Range("S7:AT16"):      Set aFromTo(2, 2) = wsDest.Range("U7")
    'Set aFromTo(3, 1) = wsSource.Range("M21:R33"):      Set aFromTo(3, 2) = wsDest.Range("M21")    'Example of a third copy/paste range - Dim aFromTo(1 to 3, 1 to 2)
    'Set aFromTo(4, 1) = wsSource.Range("S21:AT30"):     Set aFromTo(4, 2) = wsDest.Range("U21")    'Example of a fourth copy/paste range - Dim aFromTo(1 to 4, 1 to 2)

    'This will loop through the array of specified FromTo ranges and will ensure that only values are brought over
    Dim i As Long
    For i = LBound(aFromTo, 1) To UBound(aFromTo, 1)
        aFromTo(i, 2).Resize(aFromTo(i, 1).Rows.Count, aFromTo(i, 1).Columns.Count).Value = aFromTo(i, 1).Value
    Next i

End Sub
Válaszolt 14/01/2020 00:49
a forrás felhasználó

Cookies help us deliver our services. By using our services, you agree to our use of cookies. Learn more