.bat kötegelt átnevezés növeléséhez számok fname

szavazat
1

Van egy nagy mappa .cbr-es, és én átnevezés őket kibocsátási számot helyesen megrendelni őket. Mit kell tartalmaznia a ren sorban, hogy minden fájl megnövelni a számot a fájlnév keresztül Windows parancssor? Fogom ezt gyakran így fogok, hogy ez egy .bat fájlt.

Például, ahol n = a kezdeti szám és m = végső szám: n.cbr, (n + 1) .cbr, ..., (m-1) .cbr, m.cbr

A .bat Ez ideig:

ren *.cbz *.cbr
ren *.cbr <increment numbers n through m>.cbr

Egy másik változat szerint hogyan vágja minden fájl nevét úgy, hogy csak a számok előtt balra a kiterjesztés? (Az issue1.cbr a 1.cbr) keresztül akár egy .bat vagy script host fájlt?

A kérdést 12/06/2011 12:55
a forrás felhasználó
Más nyelveken...                            


2 válasz

szavazat
7

Próbáld ki ezt a batch scriptet.

@echo off
setlocal enabledelayedexpansion
set /a count=0
for /f "tokens=*" %%a in ('dir /b /od *.cbr') do (
 echo ren "%%a" !count!.cbr
 set /a count+=1
)

Átnevezi az összes fájlt egy inkrementális számláló. Az, hogy a fájlok megmarad a /ODlehetőség a DIRparancs, hogy rendezi a fájlokat lista által módosított időbélyeg.

Gondos vizsgálat, távolítsa el a ECHOparancs.

További információért olvassa el HELP DIR, HELP SETés HELP FOR.

Válaszolt 12/06/2011 19:02
a forrás felhasználó

szavazat
0
:: REN-sec.cmd ==> Rename files to increment numbers
:: Inspired on -> http://stackoverflow.com/questions/6322329#6324312
:: - (cX) 2017 adolfo.dimare@gmail.com
:: -> CAVEAT: Works on CURRENT directory!
:: - Tested on Win10 64bits
@echo off

if (%1)==()   goto _help
if (%1)==(/?) goto _example

setLOCAL EnableDelayedExpansion
rem            EnableExtensions
if (%1)==(/r) goto _recursive
if (%1)==(/R) goto _recursive
goto _current_dir

:_recursive
for /d %%A in (*.*) do (
      cd "%%~A"
      call %~dpnx0 %1 %2 %3 %4
      rem echo returning -^> call %~dpnx0 %1 %2 %3 %4
      cd ..
)
shift
goto _current_dir

:_current_dir
set /a _count=0
for %%A in (%1) do (
    set /a _count+=1

    rem Execute several times to rename 'crazy' left overs...
    FOR /L %%C IN (1,1,2) DO (
        if exist "%~2!_count!%~3%%~xA" call :skip_count %1 %2 %3 %AA
        if exist "%%~A" if not exist "%~2!_count!%~3%%~xA" ren "%%~A" "%~2!_count!%~3%%~xA"
    )
    if exist "%%~A" echo EXISTS "%%~A"
    REM if not exist "%~2!_count!%~3%%~xA" echo MISSING %~2!_count!%~3%%~xA
)
goto _out

:skip_count
    set /a _count+=1
    if exist "%~2!_count!%~3%%~x4" goto skip_count
goto _out

:_example
echo.
echo %0 USAGE EXAMPLE
echo.
echo X:\Dir\SubDir\^> dir /b
echo etc.
echo La La La.mp3
echo Le Le Le.mp3
echo Lo Lo Lo.mp3
echo Other.txt
echo.
echo X:\Dir\SubDir\^> %0 *.mp3 "" " - Su Fix"
echo.
echo X:\Dir\SubDir\^> dir /b
echo etc.
echo 1 - Su Fix.mp3
echo 2 - Su Fix.mp3
echo 3 - Su Fix.mp3
echo Other.txt
echo.

:_help
echo Rename files to increment numbers
echo.
echo CAVEAT: Works only in CURRENT directory!
echo.
echo %0 [/r] *.ext [prefix] [sufix]
echo:  /?          Help screen
echo   /r          Recurse in directories
echo   *.ext       Simple wildcard (like *.mp3) [NOT *.a.txt]
echo   prefix      Prefix to rename number
echo   sufix       sufix to rename number
echo.
echo When "" is used as prefix no prefix is put before the increment number
echo.
echo X:\Dir\SubDir\^> %0 [/r] [wildcard] [prefix] [sufix]
goto _out

:_out
:: REN-sec.cmd ==> End of file
Válaszolt 20/05/2017 16:47
a forrás felhasználó

Cookies help us deliver our services. By using our services, you agree to our use of cookies. Learn more